непонятная ошибка

Типовая конфигурация 1С: Зарплата и управление персоналом 8

непонятная ошибка

Сообщение Airin » 11 сен 2010

Добрый день!

У меня программа 1С вылетает с ошибкой "GROUP BY expression must refer to column names that appear in select list". Происходит это при проведении РКО на запросе из процедуры СформироватьЗапросПоРКОРеглВед.

Что нужно сделать, что бы это исправить?

Конфигурация 1С: Зарплата и управление персоналом 2.5.4.6 Платформа 8.1.9.54 MSSQL 2000
Airin
 
Сообщений: 22
Зарегистрирован: 08 сен 2010

Re: непонятная ошибка

Сообщение vero4kavlad » 11 сен 2010

Добрый день! Вы можете попробовать сделать так:

Функция СформироватьЗапросПоРКОРеглВед()

Запрос=Новый Запрос;
Запрос.УстановитьПараметр("Ссылка", Ссылка);
Запрос.УстановитьПараметр("Выплачено", Перечисления.ВыплаченностьЗарплаты.Выплачено);
УчетЗадолженности = ПроцедурыУправленияПерсоналом.ЗначениеУчетнойПолитикиПоПерсоналуОрганизации(глЗначениеПеременной("глУчетнаяПолитикаПоПерсоналуОрганизации"), Организация, "УчетЗадолженностиПоМесяцам");
//Запрос.УстановитьПараметр("парамУчетЗадолженностиПоМесяцам",ПроцедурыУправленияПерсоналом.ЗначениеУчетнойПолитикиПоПерсоналуОрганизации(глЗначениеПеременной("глУчетнаяПолитикаПоПерсоналуОрганизации"), Организация, "УчетЗадолженностиПоМесяцам"));
Запрос.УстановитьПараметр("парамПустаяДата", '00010101');
// Вот и исправление Вашей ошибки!

Запрос.Текст =
"ВЫБРАТЬ
| ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка КАК Ведомость,
| ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.ХарактерВыплаты,"+
?(УчетЗадолженности,"ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.ПериодРегистрации как ПериодВзаиморасчетов,"," ДатаВремя(1,1,1) как ПериодВзаиморасчетов,")+
//| ВЫБОР
//| КОГДА &парамУчетЗадолженностиПоМесяцам
//| ТОГДА ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.ПериодРегистрации
//| ИНАЧЕ &парамПустаяДата
//| КОНЕЦ КАК ПериодВзаиморасчетов,
"
| ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.Организация КАК Организация,
| ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка КАК ВедомостьНаВыплату,
| ЗарплатаКВыплатеОрганизацийЗарплата.Физлицо КАК ФизЛицо,
| СУММА(ЗарплатаКВыплатеОрганизацийЗарплата.Сумма) КАК СуммаВзаиморасчетов
|ИЗ
| Документ.ЗарплатаКВыплатеОрганизаций.Зарплата КАК ЗарплатаКВыплатеОрганизацийЗарплата
| ВНУТРЕННЕЕ СОЕДИНЕНИЕ Документ.РасходныйКассовыйОрдер.ВыплатаЗаработнойПлаты КАК РасходныйКассовыйОрдерВыплатаЗаработнойПлаты
| ПО ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка = РасходныйКассовыйОрдерВыплатаЗаработнойПлаты.Ведомость
| ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.СведенияОВыплатахРаботникамОрганизацийПоПлатежнымВедомостям КАК РанееВыплаченныеСуммы
| ПО ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка = РанееВыплаченныеСуммы.Ведомость
| И ЗарплатаКВыплатеОрганизацийЗарплата.Физлицо = РанееВыплаченныеСуммы.Физлицо
| И (РанееВыплаченныеСуммы.Регистратор <> &Ссылка)
|ГДЕ
| РасходныйКассовыйОрдерВыплатаЗаработнойПлаты.Ссылка = &Ссылка
| И ЗарплатаКВыплатеОрганизацийЗарплата.ВыплаченностьЗарплаты = &Выплачено
| И РанееВыплаченныеСуммы.Физлицо ЕСТЬ NULL
|
|СГРУППИРОВАТЬ ПО
| ЗарплатаКВыплатеОрганизацийЗарплата.Физлицо,
| ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка,
| ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.ХарактерВыплаты,
| ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.Организация"+
?(УчетЗадолженности,",ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.ПериодРегистрации","")+
//| ВЫБОР
//| КОГДА &парамУчетЗадолженностиПоМесяцам
//| ТОГДА ЗарплатаКВыплатеОрганизацийЗарплата.Ссылка.ПериодРегистрации
//| ИНАЧЕ &парамПустаяДата
//| КОНЕЦ
"
|
|ИМЕЮЩИЕ
| СУММА(ЗарплатаКВыплатеОрганизацийЗарплата.Сумма) <> 0";

Возврат Запрос.Выполнить();

КонецФункции // СформироватьЗапросПоРКОРеглВед()
vero4kavlad
 
Сообщений: 21
Зарегистрирован: 08 сен 2010


Вернуться в 1С: Зарплата и управление персоналом 8

Кто сейчас на форуме

Сейчас этот форум просматривают: нет зарегистрированных пользователей и гости: 0

cron